// written by Dylon Jamna, modified by Micah Beeler, further modified by James Tharpe
// Original code: https://pastebin.com/HKbJjKxE
// Original instructions: https://www.instructables.com/Arduino-Thermostat/

#include <LiquidCrystal.h>
#include <DHT.h>

// Sensor Configuration: Should map to temperature & humidity
// sensor connections to the Arduino
const int
	DHT_PIN = A0,
	DHT_TYPE = DHT11;

DHT sensor(DHT_PIN, DHT_TYPE);

// LCD Configuration: Should map to temperature & humidity
// sensor connections to the Arduino
const int
	LCD_PIN_RS = 11,
	LCD_PIN_EN = 12,
	LCD_PIN_D4 = 2,
	LCD_PIN_D5 = 3,
	LCD_PIN_D6 = 4,
	LCD_PIN_D7 = 5;

LiquidCrystal lcd(
	LCD_PIN_RS,
	LCD_PIN_EN,
	LCD_PIN_D4,
	LCD_PIN_D5,
	LCD_PIN_D6,
	LCD_PIN_D7);

// Button configuration
const int
	DECREMENT_BTN_PIN = 7,
	TOGGLE_BTN_PIN = 8,
	INCREMENT_BTN_PIN = 9;

// "Heater" and "cooler" configuration
const int
	HEATER_PIN = 13,
	COOLER_PIN = 10;

// Controls
bool useFahrenheit = true;
int targetF = 72, targetC = 22;

void setup() {
  // Serial (for logging)
  Serial.begin (9600);
  Serial.print("setup()\n");

  // Sensor
  sensor.begin();
  Serial.print("\tsensor initialized\n");

  // LCD
  lcd.begin(16, 2);
  lcd.setCursor(0, 0);
  lcd.clear();
  Serial.print("\tLCD initialized\n");

  // Buttons
  pinMode(INCREMENT_BTN_PIN, INPUT);
  pinMode(DECREMENT_BTN_PIN, INPUT);
  pinMode(TOGGLE_BTN_PIN, INPUT);
  Serial.print("\tButtons initialized\n");
  
  // Temperature Controllers
  pinMode(HEATER_PIN, OUTPUT);
  pinMode(COOLER_PIN, OUTPUT);
  
  Serial.print("setup() DONE\n");
}

void loop() {
  Serial.print("loop()\n");

  // Read Button State
  bool incrementTarget = digitalRead(INCREMENT_BTN_PIN);
  bool decrementTarget = digitalRead(DECREMENT_BTN_PIN);
  bool toggle = digitalRead(TOGGLE_BTN_PIN) == HIGH;
  bool wait = incrementTarget || decrementTarget || toggle;

  // Configure
  if(toggle) useFahrenheit = !useFahrenheit;
  if (incrementTarget) { targetF++; targetC++; }
  if (decrementTarget) { targetF--; targetC--; }
  const char symbol = useFahrenheit ? 'F' : 'C';
  const int target = useFahrenheit ? targetF : targetC;

  // Read Sensor Data
  float temperature = sensor.readTemperature(useFahrenheit);
  float humidity = sensor.readHumidity();
  Serial.print(
		"\t" + String(temperature) + "°" + symbol +
		", Relative Humidity " + String(humidity) +
		"% \n");
  
  // Write out to LCD
  lcdWrite(0, "Temp:   " + String(temperature) + symbol);
  lcdWrite(1, "Target: " + String(target) + ".00" + symbol);

  // Activate Temperature Control
  if(round(target) > round(temperature)) digitalWrite(HEATER_PIN, HIGH);
  else digitalWrite(HEATER_PIN, LOW);

  if(round(target) < round(temperature)) digitalWrite(COOLER_PIN, HIGH);
  else digitalWrite(COOLER_PIN, LOW);

  // Pause to allow finger to lift from button(s)
  if(wait) delay(500);
}

// Utility to simplify writing to LCD
void lcdWrite(const bool line, const String& text){
  lcd.setCursor(0, line);
  lcd.print(text);
}